传奇脚本 论坛脚本

查看自己的mirserver\Mir200中的Command.ini中的StartQuest=（这里出现的命令要记住）
然后修改自己Robot_def\RobotManage.txt中的(GMEXECUTE StartQuest @玩家坐庄开奖)   这里的出现的StartQuest改为 Comemand.ini中StartQuest= 这里的命令

修改Market_Def\娱乐\美女服务生-zzdyb.txt 中的 GMEXECUTE 元宝 <$STR(A33)> + <$STR(G38)>   这里的元宝两个字改为你服务器里调整元宝的命令

首页在QManage.txt中增加以下

[@玩家坐庄开奖]
#IF
EQUAL A33 <$USERNAME>
#ACT
goto @玩家坐庄摇筛子
break
#IF
EQUAL M45 2
#ACT
goto @玩家坐庄摇筛子
break
#IF
EQUAL M45 3
#ACT
goto @玩家坐庄摇筛子
break

[@玩家坐庄摇筛子]
#ACT
mov G43 0
mov G44 0
mov G45 0
mov G50 0
MOV M51 0
MOV M52 0
movr G43 6
inc G43 1
movr G44 6
inc G44 1
movr G45 6
inc G45 1
mov G50 <$STR(G43)>
inc G50 <$STR(G44)>
inc G50 <$STR(G45)>
PLAYDICE 3 @坐庄摇动开奖
#SAY
　\
╔═══════════════╗你所拥有的元宝数：【<$GAMEGOLD>】\
║┏━━━┓┏━━━┓┏━━━┓║\
║┃●　●┃┃●　●┃┃●　●┃║**姓名：【<$STR(A33)>】\
║┃●　●┃┃●　●┃┃●　●┃║\
║┃●　●┃┃●　●┃┃●　●┃║**本钱数：【<$STR(G38)>】\
║┗━━━┛┗━━━┛┗━━━┛║\
╚═══════════════╝你下注【<$STR(M40)>】元宝押【<$STR(S20)>】\
　\

[@坐庄摇动开奖]
#IF
EQUAL G43 <$STR(G44)>
EQUAL G44 <$STR(G45)>
#ACT
GOTO @论坛结帐1
SENDMSG 7 [美女服务生]：骰子掷出了【<$STR(G43)>】【<$STR(G44)>】【<$STR(G45)>】点【豹子】
BREAK

#IF
SMALL G50 11
#ACT
GOTO @论坛结帐2
SENDMSG 7 [美女服务生]：骰子掷出了【<$STR(G43)>】【<$STR(G44)>】【<$STR(G45)>】点【小】
BREAK

#IF
LARGE G50 10
#ACT
GOTO @论坛结帐3
SENDMSG 7 [美女服务生]：骰子掷出了【<$STR(G43)>】【<$STR(G44)>】【<$STR(G45)>】点【大】
BREAK

[@论坛结帐1]
#IF
EQUAL A33 <$USERNAME>
#ACT
INC G40 5
INC G41 5
MOV M51 <$STR(G38)>
INC M51 <$STR(G40)>
INC M51 <$STR(G41)>
DEC M51 10
GAMEGOLD + <$STR(M51)>
SENDMSG 0 [美女服务生]：**【<$USERNAME>】收回了【<$STR(M51)>】个元宝。
BREAK

#IF
#ACT
SENDMSG 6 你损失了【<$STR(M40)>】个元宝注金。
MOV S20
MOV M40 0
MOV M45 0
BREAK

[@论坛结帐2]
#IF
EQUAL A33 <$USERNAME>
#ACT
INC G40 5
INC G41 5
MOV M51 <$STR(G38)>
INC M51 <$STR(G40)>
DEC M51 <$STR(G41)>
GAMEGOLD + <$STR(M51)>
SENDMSG 0 [美女服务生]：**【<$USERNAME>】收回了【<$STR(M51)>】个元宝。
BREAK

#IF
EQUAL S20 小
#ACT
MOV M52 <$STR(M40)>
INC M52 <$STR(M40)>
GAMEGOLD + <$STR(M52)>
SENDMSG 6 你赢得了【<$STR(M40)>】个元宝注金+【<$STR(M40)>】个元宝本钱。
MOV S20
MOV M40 0
MOV M45 0
BREAK
#ELSEACT
SENDMSG 6 你损失了【<$STR(M40)>】个元宝本钱。
MOV S20
MOV M40 0
MOV M45 0
BREAK

[@论坛结帐3]
#IF
EQUAL A33 <$USERNAME>
#ACT
INC G40 5
INC G41 5
MOV M51 <$STR(G38)>
INC M51 <$STR(G41)>
DEC M51 <$STR(G40)>
GAMEGOLD + <$STR(M51)>
SENDMSG 0 [美女服务生]：**【<$USERNAME>】收回了【<$STR(M51)>】个元宝。
BREAK

#IF
EQUAL S20 大
#ACT
MOV M52 <$STR(M40)>
INC M52 <$STR(M40)>
GAMEGOLD + <$STR(M52)>
SENDMSG 6 你赢得了【<$STR(M40)>】个元宝注金+【<$STR(M40)>】个元宝本钱。
MOV S20
MOV M40 0
MOV M45 0
BREAK
#ELSEACT
SENDMSG 6 你损失了【<$STR(M40)>】个元宝本钱。
MOV S20
MOV M40 0
MOV M45 0
BREAK

建个NPC,我这里写的是 美女服务生-zzdyb.txt

(@@Sendmsg @makedrug @getback @storage @buy @sell @repair @s_repair @@useitemname @InPutString @@InPutInteger )

[@main]
欢迎光临，这里是猜点数游戏，你所拥有的元宝：【<$GAMEGOLD>】\
**姓名：【<$STR(A33)>】　**本钱数：【<$STR(G38)>】\
╔┈┈┈┈╗╔┈┈┈┈╗╔┈┈┈┈╗╔┈┈┈┈╗╔┈┈┈┈╗\
┊<查看说明/@Help>┊┊<开始坐庄/@@InPutInteger26>┊┊<下注押大/@@InPutInteger27>┊┊<下注押小/@@InPutInteger28>┊┊<退出/@main>┊\
╚┈┈┈┈╝╚┈┈┈┈╝╚┈┈┈┈╝╚┈┈┈┈╝╚┈┈┈┈╝\
押大总金额：【<$STR(G40)>】　　　　　　　　　　　剩余时间：<$STR(G39)>\
押小总金额：【<$STR(G41)>】\
你的下注情况：你下注【<$STR(M40)>】元宝押【<$STR(S20)>】　　<刷新/@main>\
<网监提示：猜点数游戏仅供娱乐，禁止进行论坛和违法的金币交易！>\

[@InPutInteger26]
#IF
LARGE G39 120
#ACT
MOV N26 0
MESSAGEBOX [提示]：**时间还未到。请等待开始！
GOTO @元宝论坛
BREAK

#IF
SMALL G39 60
#ACT
MOV N26 0
MESSAGEBOX [提示]：**时间已经结束。请等待开局！
GOTO @元宝论坛
BREAK

#IF
EQUAL A33 <$USERNAME>
#ACT
MOV N26 0
MESSAGEBOX [提示]：你目前已经是**，无法重复坐庄。
GOTO @元宝论坛
BREAK

#IF
EQUAL M45 2
#ACT
MOV N26 0
MESSAGEBOX [提示]：你已经下注押了大，无法坐庄！
GOTO @元宝论坛
BREAK

#IF
EQUAL M45 3
#ACT
MOV N26 0
MESSAGEBOX [提示]：你已经下注押了小，无法坐庄！
GOTO @元宝论坛
BREAK

#IF
SMALL N26 100
#ACT
MESSAGEBOX [提示]：请输入100以上的数值！
MOV N26 0
GOTO @元宝论坛
BREAK

#IF
CHECKGAMEGOLD < <$STR(N26)>
#ACT
MESSAGEBOX [提示]：你身上的元宝不足。
MOV N26 0
GOTO @元宝论坛
BREAK

#IF
EQUAL G38 0
#ACT
GAMEGOLD - <$STR(N26)>
MOV G38 <$STR(N26)>
MOV G42 <$STR(N26)>
SendMSG 0 %s使用<$STR(N26)>个元宝坐庄。
MOV A33 <$USERNAME>
MESSAGEBOX [提示]：使用【<$STR(N26)>】个元宝坐庄。
MOV N26 0
GOTO @元宝论坛
BREAK

#IF
LARGE N26 <$STR(G38)>
#ACT
GMEXECUTE 元宝 <$STR(A33)> + <$STR(G38)>
GAMEGOLD - <$STR(N26)>
MOV G38 <$STR(N26)>
MOV G42 <$STR(N26)>
SendMSG 0 %s使用<$STR(N26)>个元宝**成功。
MOV A33 <$USERNAME>
MESSAGEBOX [提示]：使用【<$STR(N26)>】个元宝**成功。
MOV N26 0
GOTO @元宝论坛
BREAK
#ELSEACT
MESSAGEBOX [提示]：你必须出多于【<$STR(G38)>】个元宝才能**。
MOV N26 0
GOTO @元宝论坛
BREAK

[@InPutInteger27]
#IF
LARGE G39 59
#ACT
MOV N27 0
MESSAGEBOX [提示]：下注时间还没到，现在是**时间。
GOTO @元宝论坛
BREAK

#IF
SMALL G39 5
#ACT
MOV N27 0
MESSAGEBOX [提示]：下注时间已经结束。请等待开局！
GOTO @元宝论坛
BREAK

#IF
EQUAL A33 <$USERNAME>
#ACT
MOV N27 0
MESSAGEBOX [提示]：你目前已经是**，无法下注。
GOTO @元宝论坛
BREAK

#IF
EQUAL M45 2
#ACT
MOV N27 0
MESSAGEBOX [提示]：你已经下注押了大，无法重复下注！
GOTO @元宝论坛
BREAK

#IF
EQUAL M45 3
#ACT
MOV N27 0
MESSAGEBOX [提示]：你已经下注押了小，无法重复下注！
GOTO @元宝论坛
BREAK

#IF
SMALL N27 10
#ACT
MOV N27 0
MESSAGEBOX [提示]：请输入10以上的数值！
GOTO @元宝论坛
BREAK

#IF
LARGE N27 <$STR(G42)>
#ACT
MOV N27 0
MESSAGEBOX [提示]：对不起，**的本钱已达到上限不够赔了。\目前你只可以下注【<$STR(G42)>】以下的元宝！
GOTO @元宝论坛
BREAK

#IF
CHECKGAMEGOLD > <$STR(N27)>
#ACT
MOV M45 2
MOV S20 大
GAMEGOLD - <$STR(N27)>
MOV M40 <$STR(N27)>
INC G40 <$STR(N27)>
DEC G42 <$STR(N27)>
SendMSG 4 %s使用<$STR(N27)>个元宝下注押大。
MESSAGEBOX [提示]：使用【<$STR(N27)>】个元宝下注押大。
MOV N27 0
GOTO @元宝论坛
#ELSEACT
MESSAGEBOX [提示]：你身上的元宝不足。
MOV N27 0
GOTO @元宝论坛
BREAK

[@InPutInteger28]
#IF
LARGE G39 59
#ACT
MOV N28 0
MESSAGEBOX [提示]：下注时间还没到，现在是**时间。
GOTO @元宝论坛
BREAK

#IF
SMALL G39 5
#ACT
MOV N28 0
MESSAGEBOX [提示]：下注时间已经结束。请等待开局！
GOTO @元宝论坛
BREAK

#IF
EQUAL A33 <$USERNAME>
#ACT
MOV N28 0
MESSAGEBOX [提示]：你目前已经是**，无法下注。
GOTO @元宝论坛
BREAK

#IF
EQUAL M45 2
#ACT
MOV N28 0
MESSAGEBOX [提示]：你已经下注押了大，无法重复下注！
GOTO @元宝论坛
BREAK

#IF
EQUAL M45 3
#ACT
MOV N28 0
MESSAGEBOX [提示]：你已经下注押了小，无法重复下注！
GOTO @元宝论坛
BREAK

#IF
SMALL N28 10
#ACT
MOV N28 0
MESSAGEBOX [提示]：请输入10以上的数值！
GOTO @元宝论坛
BREAK

#IF
LARGE N28 <$STR(G42)>
#ACT
MOV N28 0
MESSAGEBOX [提示]：对不起，**的本钱已达到上限不够赔了。\目前你只可以下注【<$STR(G42)>】以下的元宝！
GOTO @元宝论坛
BREAK

#IF
CHECKGAMEGOLD > <$STR(N28)>
#ACT
MOV M45 3
MOV S20 小
GAMEGOLD - <$STR(N28)>
MOV M40 <$STR(N28)>
INC G41 <$STR(N28)>
DEC G42 <$STR(N28)>
SendMSG 4 %s使用<$STR(N28)>个元宝下注押小。
MESSAGEBOX [提示]：使用【<$STR(N28)>】个元宝下注押小。
MOV N28 0
GOTO @元宝论坛
#ELSEACT
MESSAGEBOX [提示]：你身上的元宝不足。
MOV N28 0
GOTO @元宝论坛
BREAK

[@Help]
猜点游戏规则：
1)**坐庄后，其他玩家可下注，两分钟后三个骰子随机出现，\
　点数总和小于11代表小，点数总和大于10代表大，三个点数相同\
　代表豹子。
2)押大赢大，押小赢小，豹子通吃，系统不收取任何税务。\
3)正在坐庄或已下注的玩家如下线将被视做弃权，损失下注元宝。\
4)玩家下注数不能超过**坐庄的元宝总和。\
<返回/@元宝论坛>　　<离开/@EXIT>\

[@IsInFilterList]
#ACT
MESSAGEBOX [错误]：输入数据中包含了非法字符，请重新编辑！

第三步:在MerChant.txt中增加NPC

娱乐/美女服务生         zzdyb   8       10      美女服务生       0       12      0
;------------------------------------------------------------------------------------------

第四步:在MapInfo.txt中增加对应地图

[zzdyb|B013 群英仿] SAFE

第五步:在机器人AutoRunRobot.txt中增加

#AutoRun NPC SEC 1  @玩家坐庄


RobotManage.txt中增加

[@玩家坐庄]
#IF
EQUAL G39 122
#ACT
MOV A33 无
MOV G38 0
MOV G40 0
MOV G41 0
MOV G42 0

#IF
small G39 2
#ACT
MOV G39 130
GMEXECUTE StartQuest @玩家坐庄开奖
#ELSEACT
DEC G39 1
BREAK

我在努力中  

进口化工股份董事  

谢谢分享了!  

版本鉴定完毕 果然不错 没漏洞

有是一个新版本 跟新版本很快 一会我买VIP

越办越好~~~~~~~~~`  

不错，支持下  

挺好啊  

不错，看看。