任务流程：
1、先与两个教头对话，他们会让你去找天尊道长。与天尊道长对话，他会要求你去杀幻影蜘蛛。杀了幻影蜘蛛再和天尊道长对话，得知水晶的秘密。
2、在抉择之地、赤月峡谷、山谷密道中，从血巨人身上可以得到水晶。
3、在抉择之地146,110进入山谷秘道跑到178，53，进入恶魔祭坛了。
4、与震天子对话，他会让你去找血剑碎块。出来到山谷秘道跑到11，27处进入任务地图.从双头血魔身上可以得到血剑碎块.
5、从任务地图41，91出来到山谷秘道，跑到178，53，进入恶魔祭坛。再次与震天子对话，他会送你去一个地方，你可以杀*赤月恶魔得到赤月恶魔油。回来再与震天子对话，他会让你再找到邪恶巨人心脏，并告诉你，带着这两样东西去赤月魔巢打赤月恶魔，可以得到赤血魔剑。
6、恶魔祭坛出跑山谷秘道48,188进入抉择之地再跑到抉择之地217,133进入山谷秘道再跑183,178进入任务地图。从双头金刚身上可以得到邪恶巨人心脏.
7、任务地图78，12出，跑140，23，带着赤月恶魔油和邪恶巨人心脏进入赤月魔穴，杀*赤月魔,得到赤月魔剑。
[center]*****任务调试心得及对任务原脚本的一些修改说明：*****[/center]
1、@setflag是用来设置任务中的任务标记的。@flag是用来显示任务标记的。例如在调试本任务中，@setflag 玩家名 [404] 1，就可以设置玩家任务标记[404]为1，在本任务中表示玩家已经得到水晶了。@setflag 玩家名 [404] 0就可以设置玩家任务标记[404]为0，在本任务中表示玩家还没有得到水晶。在作任务时，任务标记可以用2位到3位的英文字母或数字.
2、MapQuest.txt文件的结构：
地图码 任务标记名 任务标记值 激活条件1 激活条件2 激活后执行的脚本
D10071 [409] 1 赤月恶魔1 赤月恶魔油 Q14091
含义：如果玩家的任务标记[409]的值为1，那么在D10071地图上杀*赤月恶魔1，并捡起赤月恶魔油后，就执行放在mirserver\Mir200\Envir\MapQuest_def\下的脚本文件Q14091.txt。
3、MapInfo.txt文件设地图属性的结构：
地图码 地图名 地图状态 玩家要进入时执行脚本 进入条件 禁止召唤 禁止重连(重连后进入的地图)
[D10053 山谷秘道 ] DARK CHECKQUEST(Q1406) NEEDSET_ON(406) NORECALL NORECONNECT(D10031)
NOPOSITIONMOVE 禁用条件移动 NORANDOMMOVE 禁用随机移动 NEEDHOLE ？DARK 黑暗DAY 正常*夜转换 MINE 矿区 SAFE 安全区 FIGHT 战斗区
4、在MapInfo.txt和Mongen.txt文件中比较靠前的地图和怪先刷出来，在调任务时，可以把与任务相关的地图和怪放在这两个文件的前面调试的更快。在平时，也可以把大家常去的地图放在前面（当然，你要用优先级也行）。
5、本任务中用到了以下几种任务物品：血剑碎块、水晶、赤月恶魔油、邪恶巨人心脏。要保证StdItems.DB中、任务脚本中的名称一致。用到了以下几种怪物：幻影蜘蛛、血巨人、双头血魔、赤月恶魔1、双头金刚、赤月恶魔。要保证Monster.DB中、MapQuest.txt中、Mongen.txt中、任务脚本中名称及刷新地点的一致。几种任务怪物中，只有赤月恶魔1是在季正的脚本9Wbt-D10061.txt中刷出来的，且爆出了本任务中唯一一个不是由脚本给的任务物品：赤月恶魔油。
6、原嘟嘟2.1中的脚本对话有一些不合理，进行了修改。
下面是修改后的脚本文件
下面依次列出了在任务中每个脚本文件的作用和要求,脚本的位置及文件名,脚本的内容.
*地图任务列表文件,注意在Mongen.txt中幻影蜘蛛要在地图12、D10011、D10012等中刷出来，血巨人要在地图D10031、D10032、D1004等中刷出来，双头血魔在D10053中的数量要够（10个左右），双头金刚在D10054中的数量要够（10个左右）。*
\mirserver\Mir200\Envir\MapQuest.txt
12 [401] 1 幻影蜘蛛 * Q1401
D10011 [401] 1 幻影蜘蛛 * Q1401
D10012 [401] 1 幻影蜘蛛 * Q1401
D10013 [401] 1 幻影蜘蛛 * Q1401
D1002 [401] 1 幻影蜘蛛 * Q1401
D10031 [401] 1 幻影蜘蛛 * Q1401
D10032 [401] 1 幻影蜘蛛 * Q1401
D10031 [403] 1 血巨人 * Q1403
D10032 [403] 1 血巨人 * Q1403
D1004 [403] 1 血巨人 * Q1403
D10051 [403] 1 血巨人 * Q1403
D10052 [403] 1 血巨人 * Q1403
D10053 [407] 1 双头血魔 * Q1407
D10071 [409] 1 赤月恶魔1 赤月恶魔油 Q14091
D10054 [412] 1 双头金刚 * Q1412
D10062 [412] 1 赤月恶魔 * Q14132
*地图任务脚本q1401，天尊道长让打爆子蜘蛛后,打几个幻影蜘蛛,会发生情节*
\mirserver\Mir200\Envir\MapQuest_def\q1401.txt
[@main]
#IF
check [402] 1
#ACT
break
#IF
random 5
check [401] 1
#ACT
SET [402] 1
#SAY
(原来这就是爆子蜘蛛,)如果如果现在我回去也许...他会告诉我一些秘密.\
#ELSESAY
(我听说这种怪物好象被当做测试能力的工具...)\
[/B]*地图任务脚本q1403,天尊道长讲完用水晶可以打破玉水晶防障后,打几个血巨人,发生情节*
\mirserver\Mir200\Envir\MapQuest_def\q1403.txt[/B]
[@main]
#IF
check [405] 1
#ACT
break
#IF
check [404] 1
#ACT
goto @next
break
#IF
random 5
check [403] 1
#ACT
SET [404] 1
give 水晶 1
#SAY
哈哈哈.... 这就是天尊道长 在讲故事时所提到的那种水晶.(使用这个水晶我可以进到被道力防障所关闭的那个房间.)
[@next]
#IF
random 20
#SAY
被道力防障所关闭的房间在哪里?\
***地图任务脚本q1404,设在MapInfo.txt中作为进入地图的条件在MapInfo.txt中的语句形式为:***
***[D10061 恶魔祭坛 0] DARK CHECKQUEST(Q1404) NEEDSET_ON(404) NORECALL NORECONNECT(D10031)***
\mirserver\Mir200\Envir\MapQuest_def\q1404.txt
[@main]
#IF
check [408] 1
#ACT
break
#IF
check [405] 1
#ACT
break
#IF
check [404] 1
checkitem 水晶 1
#ACT
take 水晶 40
SET [405] 1
#ELSESAY
(怎么我总被这讨厌的道力防障推回来!!)
***地图任务脚本q1406,设在MapInfo.txt中作为进入地图的条件在MapInfo.txt中的语句形式为:***
***[D10053 山谷秘道 ] DARK CHECKQUEST(Q1406) NEEDSET_ON(406) NORECALL NORECONNECT(D10031)***
\mirserver\Mir200\Envir\MapQuest_def\q1406.txt
[@main]
#IF
check [407] 1
#ACT
break
#IF
check [406] 1
#ACT
SET [407] 1
#ELSESAY
(我感到似乎哪里出错了...)
*地图任务脚本q1407,季正让去找血剑碎块,杀几个双头血魔后,发生情节*
\mirserver\Mir200\Envir\MapQuest_def\q1407.txt
[@main]
#IF
check [409] 1
#ACT
break
#IF
check [408] 1
#SAY
(现在我要回到震天子那儿去了解更多的信息...)\
#ACT
break
#IF
random 5
check [407] 1
#SAY
只要看到它，我就变得想喝它的血...现在我要回到震天子那儿去了解更多的信息.\
#ACT
give 血剑碎块 1
SET [408] 1
*地图任务脚本q14091,季正试练时的情节*
\mirserver\Mir200\Envir\MapQuest_def\q14091.txt
[@main]
#IF
check [410] 1
#ACT
break
#IF
check [409] 1
#SAY
嗯，这是什么?赤月恶魔油??它能用来做什么呢??我可得把它保管好.... \
#ACT
SET [410] 1
****地图任务脚本q1411,设在MapInfo.txt中作为进入地图的条件在MapInfo.txt中的语句形式为:****
****[D10054 山谷秘道 ] DARK CHECKQUEST(Q1411) NEEDSET_ON(411) NORECALL NORECONNECT(D10031)****
\mirserver\Mir200\Envir\MapQuest_def\q1411.txt
[@main]
#IF
check [412] 1
#ACT
break
#IF
check [411] 1
#ACT
SET [412] 1
#ELSESAY
(我还有什么事情没有做了吗...)我一定要把赤月恶魔的秘密找出来!!\
*地图任务脚本q1412,季正讲完得血魔剑方法后,杀几个双头金刚后,发生情节*
\mirserver\Mir200\Envir\MapQuest_def\q1412.txt
[@main]
#IF
check [413] 1
#ACT
break
#IF
random 5
check [412] 1
#SAY
(这个是邪恶巨人心脏吗？让我好好看看..)啊,这正是我要进行伪装所必须的啊。\ \
#ACT
give 邪恶巨人心脏 1
SET [413] 1
*地图任务脚本q14132,最后得血魔剑的脚本*
\mirserver\Mir200\Envir\MapQuest_def\q14132.txt
[@main]
#IF
check [414] 1
#ACT
break
#IF
check [413] 1
checkitem 赤月恶魔油 1
checkitem 邪恶巨人心脏 1
#ACT
give 赤血魔剑 1
take 赤月恶魔油 1
take 邪恶巨人心脏 1
SET [414] 1
#SAY
赤血恶魔已经*亡, 现在世界恢复平静...\
*天尊的脚本*
\mirserver\Mir200\Envir\market_def\6wrt-11.txt
[@main]
#IF
check [403] 1
#SAY
贫道就是这个道馆的馆长<破关号>. 见到像你这样年少气盛的勇士，想起了很久以前我年轻时候的事情. 其中，一想到 <季正>,我就热血沸腾 哦,你可能太年轻不了解此事. 你想听季正的故事吗? \ <听/@hear> <不听/@nohear>
#ACT
break
#IF
check [402] 1
#SAY
你打败爆子蜘蛛胜利归来，祝贺你.我现在告诉你所想知道的事情. \ <盗走破关珍剑的恶人是谁?/@next_quest>
#ACT
break
#IF
check [401] 1
#SAY
你还没有打败爆子蜘蛛. 在打败爆子蜘蛛之前， 我不能告诉你这个秘密. \ <关 闭/@exit>
#ACT
break
#IF
check [400] 0
#SAY
贫道就是这个道馆的馆长<破关号>. 见到像你这样年少气盛的勇士，想起了很久以前我年轻时候的事情. 其中，一想到<季正>,我就热血沸腾 哦,你可能太年轻不了解此事. 你想听季正的故事吗? \ <听/@hear> <不听/@nohear>
#ELSESAY
看来施主您对以前的事情很感兴趣. 好，你想知道什么? \ <想了解破关珍剑/@quest>
[@next_quest]
#IF
#SAY
关于他没有任何传言. 他犯了滔天大罪，很多人都追他要他的命 前任馆长可怜他，收留了他， 结果这个忘恩负义的家伙竟然盗走了祖传之宝. \ <破关珍剑是什么样的剑?/@next_quest1>
[@next_quest1]
#IF
#SAY
这把宝剑的制作方法和所有与宝剑有关联的所有事情， 随着宝剑被盗全部消失了.具体事情贫道也不清楚.人们说这个宝剑可以呼风唤雨，召唤天龙,但是这只是由于人们对所失去的宝剑的怀念和爱心，才会这样传下来. \ <破关珍剑在哪里? /@next_quest2>
[@next_quest2]
#IF
#SAY
据贫道小时候听前任馆长所讲, 偷走破关珍剑的盗贼逃去的地方是灌木林那一边的红月峡谷. 当时为了追捕他，很多武林人士组成追捕队 进入红月峡谷,但是那么多人没有一个人活着出来 贫道凭借七星神君的法力算了一卦.结果发现红月峡谷最深处有一个很强大的恶魔 我想那些惨*事件跟这个恶魔有关. \ <知道了. 多谢赐教./@next_quest3>
[@next_quest3]
#IF
#SAY
很久以前红月峡谷没有被恶魔所占领时， 那里是玉水晶的主产地. 给玉水晶注入特殊的气运, 就可以制成强有力的防帐 只有具有同样气运的玉水晶才能打破它, 也就是说只有制造防帐的人才能做得出玉水晶钥匙 进入红月峡谷的高手们，说不定用玉水晶留下点什么 我和你说的话你一定要记住阿 千万不要忘记. <关 闭/@exit>
#ACT
SET [403] 1
[@nohear]
哎.事情都过去了，听有什么用? 你还是走吧.这里对你来说不是长久之地 \ <请求/@pre_hear>继续听 <关 闭/@exit>
[@pre_hear]
什么？还想听?看来你很喜欢听，是不是？ \ <下一个/@hear>
[@hear]
你这么想知道以前的事情？那时候你还没有出世呢， 你的好奇心可真强阿.好，我也回忆一下以前的事情 听我讲吧. \ <下一个/@next>
[@next]
是大约90年前的事情. 当时我还只是一个刚过20岁的少年. 但是我的武功当时在道馆就已经在前十名里面不是我在夸自己，而是这是事实. \ <下一个/@next1>
[@next1]
当时因为一件事情，比奇很吵闹 就是关于那个盗贼 <季正>乱窜有名的道馆偷取各种秘籍和宝物的事情 \ <下一个/@next2>
[@next2]
受害程度越来越严重，于是武林人士决定将 <季正>捉拿归案 并且将<季正>陷入陷阱 但是我们太小瞧了这个盗贼谁能想到一个小偷竟然练就绝世武功呢? \ <下一个/@next3>
[@next3]
3，4代弟子们被彻底打败之后，各门派开始动员1，2代武林高手 ''''季正''''虽然每次都巧妙地夺过包围 但是在沃玛森林终于被抓住了。嘿，你别打瞌睡阿. 现在开始才是我真正辉煌的时候. \ <下一个/@next4>
[@next4]
正，邪派近14人一起包围他，可是他却一点都不怕 真不简单. 我们的目的并不是要他的命，而是要拿回那本武功秘籍 我们劝他把秘籍交出来，但是他不听，于是战斗开始了\<下一个/@next5>
[@next5]
14个人一起攻击，他都没有被屈服. 一来他有一身绝顶武功，更为重要的是 各派武林高手心不和，没能发挥出自己最高水平 所以我让所有人退下，我一个人和他进行一对一决斗. \ <下一个/@next6>
[@next6]
在激烈的战斗中我负了重伤. 同时我也在他的腿上留了很长的伤痕 看他站都站不稳，我放松警惕. 趁这个机会 ,<季正>用神奇的轻功逃出了包围我按着地上的血痕追捕他，但是在灌木林失去了他的踪影 \ <下一个/@next7>
[@next7]
<季正>一消失，秘籍的去向也成了一个迷. 那时有传闻说欲想独占武功秘籍的邪派将<季正>藏起来， 为此正，邪两派之间发生了激烈的战争.战争持续了10年之久，却没有任何结果， 正，邪两派之间的战争也就不了了之了 \ <下一个/@next8>
[@next8]
从此没有人再见到 <季正>都以为这将成为江湖一大不解之迷. 但是，最近在灌木林最深处发现了一个大洞, 有传闻说那里藏着季正所偷走的秘籍. \ <下一个/@next9>
[@next9]
但是,那里有很多可怕的怪物 随便进入会有生命危险的。我已经老了，离*不远了. 只要我不是负责道馆的馆长，现在我就想去确认一下.. \ <下一个/@next10>
[@next10]
#IF
#SAY
这个故事到此为止，你该走了. \ <关 闭/@exit>
[@quest]
#IF
#SAY
破关珍剑...这把宝剑曾经在我道馆所藏 破关珍剑里蕴藏着神灵的气运， 传说它可以打破百妖千邪之气运... 但是，很久以前被一名恶人所盗走,成为神话里的宝剑.但是，若说破关珍剑确实存在,我倒是想起一个地方 \ <什么地方?/@quest1>
[@quest1]
#IF
#SAY
那个地方.. 哎..那里太危险不能随便告诉人的. 知道你很好奇，但是因为一时好奇而丢掉性命， 那岂不是贫道把你推向火坑里吗？. \ <我可以克服任何难关/@quest2>
[@quest2]
#IF
#ACT
SET [401] 1
close
*季正的脚本*
\mirserver\Mir200\Envir\market_def\9Wbt-D10061.txt
[@main]
#IF
check [411] 1
#ACT
break
#IF
check [410] 1
#SAY
瓶子里装的是我杀*红月恶魔的来的魔血... 把这个血抹在衣服上，利用邪恶巨人心脏伪装成恶魔你就可以得到赤血魔剑消灭红月恶魔，除掉恶魔，这一艰巨任务全靠你了 . 你一个人是很难战胜红月恶魔，一定要和众多高手一起去.. \ <关 闭/@exit>
#ACT
SET [411] 1
break
#IF
check [409] 1
#SAY
你还没有杀*红月恶魔... 我再把你送回去 你可一定要通过这次考验啊.. \ \
<去考验/@next_quest>
#ACT
break
#IF
check [408] 1
checkitem 血剑碎块 1
#SAY
赤血魔剑碎块带来了吗？我要再一次考验你的能力 你要通过这个考验，给我带来魔血. 这样，我就会告诉你得到赤血魔剑的方法<去考验/@next_quest>
#ACT
break
#IF
check [406] 1
#SAY
快, 快去给我拿来赤血魔剑. 这是不祥之剑. 趁这把剑还未被别人抢到手，你一定要把它找回来. \ \
<关 闭/@exit>
#ACT
break
#IF
check [405] 1
#SAY
快来,我的朋友! 这么长时间我一直在等着你.. \ \
你是不能躲过命运的安排.... 你愿意继承我意，开始这艰难的旅途吗？ \ <我非常愿意/@next>
[@next]
#IF
#SAY
好，或许这一切都是命运的安排. 我没*活到今天等到了你，你得到玉水晶来找我 这都是缘分.. 我的名字是季正，以前人们都叫我震天子. 我出身于银杏峡谷，5岁开始学武，30岁的时候已经是天下无敌\
我凭自己武艺高强，骄傲蛮横，行事霸道，结了很多恩怨但是现在我对世事不闻不问 \ \
<下一个/@next1>
[@next1]
#IF
#SAY
有很长一段时间我为了寻找武艺高超的怪物在江湖没了踪影， 后来终于来到了这个红月峡谷的最顶层\
我在一个潮湿臭气满天的房间看到了一个巨大的怪物... \
那个怪物在疯狂地咆哮着，爆发着内心的愤怒... \
我被这个怪物强大的力量惊呆了... 我想到无论如何都要把这个怪物杀掉，不然太危险了 \
<所以需要破关珍剑./@next2>
[@next2]
#IF
#SAY
是的.为此我到山下的道馆，求他们借给我他们的馆中之宝破关珍剑, \
但是，由于当时我在江湖中声誉不是很好，所以他们不但不相信我说的话, 还把我赶出门外。我一气之下用武力把那把破关珍剑抢到手 之后就来到了这个地方 事情的祸根就是从此开始... 当时我傲气十足 \ \
<下一个/@next3>
[@next3]
#IF
#SAY
知道我抢到了宝物，很多人为了得到那个宝物来杀我 \
那天来红月峡谷的所有人都被那个巨大的恶魔中邪, 充满了杀气 . 人们互相残杀，尸体遍布在整个峡谷，血流成河... 值得庆幸的是我有道门无价之宝破关珍剑， 所以没有中那个恶魔的邪咒,
但是还是杀*了几个无辜的人 . \ \
<下一个/@next4>
[@next4]
#IF
#SAY
我对那个怪物...对那个红月恶魔恨之入骨. 但是只凭愤怒和憎恨士没有办法战胜恶魔 \
我把剑插入红月恶魔心脏的瞬间，我已经被恶魔的邪气包围住 破关珍剑没能战胜我心中的邪恶，我人包括破关珍剑都没能保住 破关珍剑也成了邪恶之剑。 <我该怎么做才能杀*红月恶魔?/@next5>
[@next5]
#IF
#SAY
虽然当时红月恶魔打败了我和破关珍剑， 但是破关珍剑所具有的威力带给红月恶魔的打击也非常大. 所以虽说过了很长的岁月，但是红月恶魔还没有恢复元气 \
再加上你没有染上恶魔的邪气，我干肯定你一定能打败它 红月恶魔所犯下的罪过，是不能饶恕的 一定要把它消灭掉，你要记住我将要说的话 <你尽管下吩咐吧./@next6>
[@next6]
#IF
#SAY
自从我沾上红月恶魔的魔血变成人魔之后... 我受破关珍剑，不，受红月魔剑的引诱在赤血峡谷乱杀无辜. \
这种情形持续了100多年，终于打断了赤血宝剑，我也回复了神志 \
我从邪恶里清醒过来，得到了醒悟，\
就算我*了，我的灵魂和肉体都会在一起。现在我要和你讲的是，请务必把赤血魔剑碎块找回来，不然，你会和我同样下场...我会一直在这里等待你回来。\<关 闭/@exit>
#ACT
SET [406] 1
[@next_quest]
#IF
checkhum D10071 2
#SAY
别人正在接受考验.. 你稍等.. \ <关 闭/@exit>
#ELSEACT
take 血剑碎块 1
SET [409] 1
MONCLEAR D10071
PARAM1 D10071
PARAM2 17
PARAM3 21
MONGEN 赤月恶魔1 1 0
MAP D10071
*白*门教练的脚本*
\mirserver\Mir200\Envir\market_def\9Wtt-11.txt
[@main]
#IF
check [400] 0
#SAY
破关珍剑? 哦...看来学徒们和你说了一些废话 \
对我们这些修道的人来说，那种废铁是没用的... \ <原来如此, 破关珍剑真的存在吗?/@next> <原来如此. 看来不能依靠身外之物./@deney>
#ELSESAY
如果你实在很好奇, 那就去找馆主吧.. \ <关 闭/@exit>
[@deney]
#IF
#SAY
对，就要这样. 我要好好教训这些不懂事的家伙 请施主避开一会儿. \ <关 闭/@exit>
[@next]
#IF
#SAY
破关珍剑是我们道馆镇馆之宝... 那是许多年以前的事情了我也是听馆主无意中谈起才知道的... \ <关 闭/@exit>
#ACT
SET [400] 1
*爆物机率文件*
\mirserver\Mir200\Envir\MonItems\赤月恶魔1.txt
1/1 赤月恶魔油
论坛一条龙
|
沉默卡
喧嚣卡
抢沙发
显身卡