盛大模式拜师系统脚本

显示全部楼层 · 2012-11-17 19:29:12

以下脚本！目前支持3KM2引擎！
可以收N个徒弟，师傅封号里不显示信息，徒弟封号里显示XXX的大弟子，二弟子
注意:修改String.ini文件里的NoMasterName=%s的%s徒弟不然游戏里无显示
游戏命令：
@收徒是否收徒,防止恶意骚扰默认为拒绝

脚本变量：
<$SFNAME> 师傅名
<$TDNAME1>大徒弟
<$TDNAME2>二徒弟
<$TDNAME3>三徒弟
<$TDNAME4>四徒弟
<$TDNAME5>五徒弟
触发 QFunction-0.txt
[@RevMaster]
对方想拜你为师，你是否想收此人为徒？ \ \
『<同意/@ResposeMaster>』 \
『<不同意/@ResposeMasterFail>』
[@ResposeMaster]
#IF
#ACT
master responsemaster1 ok
close
[@ResposeMasterFail]
#if
#act
master responsemaster1 fail
[@EndMaster]
#if
#act
SENDMSG 0 %s完成了拜师收徒仪式!
[@EndMasterFail]
拜师失败！\ \
〖<关闭/@exit>〗
[@RevUnMaster]
对方向你请求脱离师徒关系，你是否答应？ \ \
『<我愿意/@ResposeUnMaster>』
〖<退出/@Exit>〗
[@ResposeUnMaster]
#if
#act
unmaster REQUESTUNMASTER MASTER
[@PoseUnMasterEnd]
呵呵，你已经与徒弟脱离师徒关系了！！！ \ \
『<退出/@exit>』
[@RequestUnMasterEnd]
呵呵，你已经脱离师徒关系了！！！ \ \
『<退出/@exit>』
;------------------------------------------------------------------------------------
(@@InPutInteger @@InPutString)
%100
[@main]
你想做什么？\
<师傅如何收徒/@如何收徒> <我想将徒弟逐出师门/@想删除徒弟>\
<我要拜师/@拜师>\
<解除师徒关系/@解除师徒关系>\
<离开/@exit>\

[@想删除徒弟]
你想将哪位弟子逐出师门：\
<大徒弟/@大徒弟>:<$TDNAME1>\
<二徒弟/@二徒弟>:<$TDNAME2>\
<三徒弟/@三徒弟>:<$TDNAME3>\
<四徒弟/@四徒弟>:<$TDNAME4>\
<五徒弟/@五徒弟>:<$TDNAME5>\ \
<返回/@main>
[@大徒弟]
#IF
#ACT
DELAPPRENTICE <$TDNAME1>
break
[@二徒弟]
#IF
#ACT
DELAPPRENTICE <$TDNAME2>
break
[@三徒弟]
#IF
#ACT
DELAPPRENTICE <$TDNAME3>
break
[@四徒弟]
#IF
#ACT
DELAPPRENTICE <$TDNAME4>
break
[@五徒弟]
#IF
#ACT
DELAPPRENTICE <$TDNAME5>
break
[@NoApprentice]
你没有徒弟还想删除徒弟？没事找事吧？
[@DelApprenticeEnd]
删除徒弟成功。
[@DelApprenticeFail]
你输入的名字是你的徒弟名字？搞清楚没有？

[@拜师]
想拜师呀，想拜哪位为师： <师父名字/@@InPutString51> ←输入师父名字！\ \
你的师父要在线才可以，开始拜师。\ \
〖<返回/@main>〗

[@InPutString51]
#if
CheckMaster
#act
Break
#say
你都都已经拜了别人为师，怎么还拜师！！！ \ \
〖<返回/@main>〗\
\
#if
CHECKLEVELEX > 35
#say
你都35多级了还要找师父？\ \
〖<返回/@main>〗\
\
#act
Break
#if
#act
master Receiver <$STR(S51)> 44
[@MasterNoRead]
对方拒绝收徒,需要对方输入命令: @<$CMD_READMASTERMSG> 允许收徒后才能拜师\ \
[@MasterNoRead1]
对方已不能再收徒弟了！！！请另找别的师傅吧
[@StartGetMaster]
拜师仪式正式开始。\ \
你是否确认拜师？\ \
『<确认/@RequestMaster>』
[@StartMaster]
拜师仪式正式开始。\ \
对方已经向你提出拜师请求。\ \
[@RequestMaster]
#if
#act
master requestmaster <$STR(S51)>
CLOSE
[@WateMaster]
#if
#act
SENDMSG 0 %s面对着自己仰慕已久的英雄深深鞠了一躬，请求对方收自己为徒!
[@MasterErr]
你找了个什么人做师父，怎么现在还是别人的徒弟？
[@MasterLevelErr]
你找个什么师父呀，等级这么低？还没达到45级？\ \
[@MasterCheckDir]
对方没在线上\\
[@HumanTypeErr]
此人不可以做你的师父。
[@解除师徒关系]
#if
havemaster
#act
unmaster
#elsesay
你都没师父，跑来做什么？？\ \
〖<返回/@main>〗

[@UnMasterTypeErr]
你对面站了个什么东西，怎么不太象人来的。\ \
〖<返回/@main>〗
[@UnIsMaster]
必须由徒弟发出请求！！！\ \
〖<返回/@main>〗
[@UnMasterError]
不要来捣乱！！！\ \
〖<返回/@main>〗
[@StartUnMaster]
出师仪式现在开始！！！\ \
是否确定真的要脱离师徒关系？\ \
『<确定/@RequestUnMaster>』
[@WateUnMaster]
出师仪式现在开始！！！\ \
[@RequestUnMaster]
#if
havemaster
#act
unmaster requestunmaster
[@WateUnMaster]
你已向对方发出请求，请耐心等待对方的答复。
[@UnMasterCheckDir]
按正常出师步骤，师傅必须在线才能出师，\
如果师傅不在线上，你只能选择强行出师了。注意强行出师\
我可是要收费 \ \
『<我要强行出师/@fUnMaster>』\
〖<返回/@main>〗
[@fUnMaster]
#if
checkitem 金条 1
havemaster
#act
take 金条 1
unmaster requestunmaster force
#elsesay
要收一根金条的手续费，你没有金条，\
『<确定/@exit>』\
\
[@ExeMasterFail]
你都没师父，跑来做什么？ \ \
[返回/@main]
[@RequestUnMasterEnd]
呵呵，你已经脱离师徒关系了！！！ \ \
『<退出/@exit>』
[@如何收徒]
『师父』--人物等级到达45级，就可以收徒弟了！\
『徒弟』--人物等级必须在35级以下才能做别人的徒弟！\
『出师』--徒弟等级到达42级，徒弟自动出师！\
『收徒』--双方必须面对面！由徒弟点我要拜师即可\
『好处』--徒弟出师后师父会自动获得5点声望！\
『声望』--声望可以兑换荣誉值！荣誉值可以领取荣誉勋章\
『命令』：@允许师徒传送 @师徒传送\
<返回/@main>\